Πώς να χρησιμοποιήσετε το Caps Lock ως κλειδί τροποποίησης στα Windows

Το πλήκτρο Caps Lock καταλαμβάνει το βασικό πληκτρολόγιο και δεν τραβάει το βάρος του. Αυτό το εύκολο σενάριο AutoHotkey θα μετατρέψει το Caps Lock σε κλειδί τροποποίησης, ώστε να μπορείτε να το χρησιμοποιήσετε για προσαρμόσιμες συντομεύσεις.

Τα βασικά

Αυτό το σενάριο θα σας επιτρέψει να πατήσετε Caps Lock+G για να στείλετε γρήγορα κείμενο Google από οπουδήποτε στα Windows ή να πατήσετε το Caps Lock+D για να αναζητήσετε τον ορισμό μιας λέξης στο λεξικό. Αυτές οι συντομεύσεις είναι φυσικά προσαρμόσιμες.

Το καλύτερο από όλα, αυτό το έξυπνο σενάριο εξακολουθεί να σας επιτρέπει να χρησιμοποιείτε κανονικά το Caps Lock. Μπορείτε να ενεργοποιήσετε και να απενεργοποιήσετε το Caps Lock πατώντας το γρήγορα δύο φορές. Εάν δεν το κάνετε, το Caps Lock θα λειτουργεί ως πλήκτρο τροποποίησης για συντομεύσεις.

AutoHotkey 101

Το AutoHotkey είναι μια δωρεάν εφαρμογή των Windows που βρίσκεται στο παρασκήνιο και εκτελεί σενάρια. Μπορείτε να γράψετε αυτά τα σενάρια μόνοι σας ή να τα κατεβάσετε. Τα σενάρια γενικά περιμένουν να πατηθεί το πλήκτρο και εκτελούν μια ενέργεια. Με αυτόν τον τρόπο, το AutoHotkey είναι ένας γρήγορος τρόπος για να αντιστοιχίσετε ξανά κλειδιά στα Windows ή να εκχωρήσετε διαφορετικές ενέργειες σε κλειδιά.

Για παράδειγμα, δείξαμε πώς μπορείτε να χρησιμοποιήσετε το AutoHotkey για να απενεργοποιήσετε το κλειδί των Windows, εμποδίζοντάς το να ανοίξει το μενού Έναρξη και να σας απομακρύνει από παιχνίδια υπολογιστή πλήρους οθόνης. Δεν χρειάζεται να αφαιρέσετε το κάλυμμα του πληκτρολογίου.

  Πώς να επιλέξετε μια ακριβή ανάλυση οθόνης στο Mac σας

Εγκαταστήστε το AutoHotkey και λάβετε το σενάριο

Κατεβάστε το AutoHotkey και εγκαταστήστε το για να ξεκινήσετε. Στη συνέχεια, κατεβάστε το σενάριο του CapsLock Modifier.

Εξαγάγετε το αρχείο σεναρίου AHK από το αρχείο αρχειοθέτησης ZIP και τοποθετήστε το σε οποιονδήποτε φάκελο στον υπολογιστή σας. Για να το εκτελέσετε με το AutoHotkey, κάντε δεξί κλικ στο σενάριο και επιλέξτε «Εκτέλεση σεναρίου».

Το σενάριο εκτελείται τώρα στο παρασκήνιο. Για να ενεργοποιήσετε και να απενεργοποιήσετε το Caps Lock, πατήστε γρήγορα δύο φορές το πλήκτρο Caps Lock.

Εάν δεν πατήσετε δύο φορές, το Caps Lock λειτουργεί απλώς ως κλειδί τροποποίησης. Με τις ενσωματωμένες λειτουργίες στο σενάριο, μπορείτε να χρησιμοποιήσετε τις ακόλουθες συντομεύσεις οπουδήποτε στα Windows:

Πατήστε Caps Lock + d για να βρείτε τον ορισμό του λεξικού μιας επιλεγμένης λέξης.
Πατήστε Caps Lock + g για αναζήτηση στο Google για το επιλεγμένο κείμενο οπουδήποτε στα Windows.
Πατήστε Caps Lock + t για να βρείτε την επιλεγμένη λέξη σε έναν θησαυρό.
Πατήστε Caps Lock + w για να αναζητήσετε το επιλεγμένο κείμενο στη Wikipedia.

Θέλετε περισσότερες συντομεύσεις; Μπορείτε να δημιουργήσετε το δικό σας με λίγη γνώση των σεναρίων AutoHotkey.

Για να ελέγξετε το AutoHotkey, αναζητήστε το εικονίδιο AutoHotkey στην περιοχή ειδοποιήσεών σας—έχει ένα πράσινο φόντο με ένα λευκό H πάνω του. Για να διακόψετε την εκτέλεση του σεναρίου, απλώς κάντε δεξί κλικ στο εικονίδιο AutoHotkey και επιλέξτε «Έξοδος».

  Πώς να λάβετε μια προσαρμοσμένη ειδοποίηση Windows 10

Πώς λειτουργεί?

Εάν θέλετε να δείτε τι κάνει το σενάριο, κάντε δεξί κλικ σε αυτό και επιλέξτε “Επεξεργασία Σεναρίου”. Αυτό θα ανοίξει το σενάριο στο Σημειωματάριο και μπορείτε να εξετάσετε τον κώδικά του. Το σενάριο είναι αρκετά σύντομο και κατανοητό. Συνιστούμε να μην κάνετε λήψη και εκτέλεση περίεργων σεναρίων χωρίς να τα κοιτάξετε και να τα καταλάβετε πρώτα.

Αυτό το σενάριο μας έστειλε ο Dave Kellog. Ακολουθεί το μαγικό μέρος του σεναρίου που κάνει το Caps Lock να λειτουργεί ως πλήκτρο τροποποίησης εάν πατηθεί δύο φορές:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Αυτό το bit περιμένει να δει εάν το Caps Lock πατηθεί δύο φορές και ενεργοποιεί ή απενεργοποιεί το Caps Lock. Διαφορετικά, το σενάριο καταγράφει το Caps Lock και το χρησιμοποιεί για συντομεύσεις τροποποιητών.

Το υπόλοιπο σενάριο περιέχει τις ενέργειες συντόμευσης και μια χρήσιμη λειτουργία προχείρου που αποθηκεύει τα περιεχόμενα του προχείρου σας και τα επαναφέρει. Αυτό το μέρος είναι αρκετά απαραίτητο, καθώς οι λειτουργίες του τροποποιητή χρησιμοποιούν το πρόχειρο για να κάνουν ενέργειες στο επιλεγμένο κείμενο.

Θέλετε να δείτε το πλήρες σενάριο χωρίς να το κατεβάσετε; Εδώ είναι:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Έχουμε δει στο παρελθόν σενάρια AutoHotkey που μετατρέπουν το Caps Lock σε κλειδί τροποποίησης, αλλά ποτέ ένα που διατηρεί το Caps Lock ως εναλλαγή αν το πατήσετε δύο φορές. Είναι πολύ έξυπνο. Ευχαριστούμε και πάλι τον Dave Kellog που μας το έστειλε.

  Δημιουργία, κοινή χρήση και συνεργασία σε αυτοκόλλητες σημειώσεις και λίστες υποχρεώσεων